JSON serialization in X++

JSON Serialization in X++

TestCustTransExportRequest Class

The TestCustTransExportRequest class represents the request data for exporting customer transactions.

[datacontractAttribute] class TestCustTransExportRequest { String10 dataAreaId; CustAccount custAcc; [DataMemberAttribute("dataAreaId")] public String10 parmDataAreaId(String10 _dataAreaId = dataAreaId) { dataAreaId = _dataAreaId; return dataAreaId; } [DataMemberAttribute("CustomerAccount")] public CustAccount parmCustAcc(CustAccount _custAcc = custAcc) { custAcc = _custAcc; return custAcc; } }

TestCustTransListResponseContract Class

The TestCustTransListResponseContract class is a response data contract representing customer transaction details. This class includes properties for various transaction details such as type, date, amount, and currency. The [DataMemberAttribute] attribute is used to specify the names of these properties in the serialized JSON.

[datacontractAttribute] class TestCustTransListResponseContract { Str60 transType; ExchRate exchRate; String30 transDate; AmountCur amountCur; CurrencyCode currency; TransactionTextLarge description; AmountMST amountMST; AmountCur remainAmountBal; String10 dataAreaId; CustAccount custAcc; [DataMemberAttribute("Channel")] public String10 parmDataAreaId(String10 _dataAreaId = dataAreaId) { dataAreaId = _dataAreaId; return dataAreaId; } [DataMemberAttribute("Customer Id")] public CustAccount parmCustAcc(CustAccount _custAcc = custAcc) { custAcc = _custAcc; return custAcc; } [DataMemberAttribute("Transaction type")] public Str60 parmTransType(Str60 _transType = transType) { transType = _transType; return transType; } [DataMemberAttribute("Date")] public String30 parmTransDate(String30 _transDate = transDate) { transDate = _transDate; return transDate; } [DataMemberAttribute("Description")] public TransactionTextLarge parmDescription(TransactionTextLarge _description = description) { description = _description; return description; } [DataMemberAttribute("Amount in currency")] public AmountCur parmAmountCur(AmountCur _amountMST = amountCur) { amountCur = _amountMST; return amountCur; } [DataMemberAttribute("Currency")] public CurrencyCode parmCurrencyCode(CurrencyCode _currency = currency) { currency = _currency; return currency; } [DataMemberAttribute("Amount in accounting currency")] public AmountMST parmAmountMST(AmountMST _amountMST = amountMST) { amountMST = _amountMST; return amountMST; } [DataMemberAttribute("Exchange rate")] public exchRate parmExchRate(ExchRate _exchRate = exchRate) { exchRate = _exchRate; return exchRate; } [DataMemberAttribute("Balance")] public AmountCur parmRemainAmount(AmountCur _remainAmountBal = remainAmountBal) { remainAmountBal = _remainAmountBal; return remainAmountBal; } }

TestCustTransExportResponse Class

The TestCustTransExportResponse class represents the response data for exporting customer transactions. It contains a list of transaction data. This class is designed to be serialized into a JSON structure containing an array of transactions.

class TestCustTransExportResponse { List transactionData = new List(Types::Class); CustAccount custAcc; String10 dataAreaId; [DataMemberAttribute("Transactions"),DataCollectionAttribute(Types::Class, classStr(TestCustTransListResponseContract))] public List parmTransactionData(List _transactionData = transactionData) { transactionData = _transactionData; return transactionData; } }

TestCustTransExportService Class

The TestCustTransExportService class is a custom web service class that processes export transactions based on the provided request. It uses the other three classes to gather and structure the transaction data, and then returns the response in the specified JSON format.

class TestCustTransExportService extends SysOperationServiceBase { public TestCustTransExportResponse processExportTransaction(TestCustTransExportRequest _requestedCustomer) { TestCustTransExportResponse response = new TestCustTransExportResponse(); CustTrans custTrans; List custTransactionsList = new List(Types::Class); CustAccount custAccount = _requestedCustomer.parmCustAcc(); Microsoft.Dynamics.Ax.Xpp.ErrorException errorEx; try { changecompany(_requestedCustomer.parmDataAreaId()) { while select custTrans where custTrans.AccountNum == custAccount && (custTrans.AmountCur - custTrans.SettleAmountCur) != 0 { TestCustTransListResponseContract custTransListContract = new TestCustTransListResponseContract(); custTransListContract.parmCustAcc(custTrans.AccountNum); custTransListContract.parmDataAreaId(custTrans.DataAreaId); custTransListContract.parmTransType(enum2Str(custTrans.TransType)); custTransListContract.parmTransDate(date2StrUsr(custTrans.TransDate)); custTransListContract.parmDescription(custTrans.Txt); custTransListContract.parmamountCur(custTrans.AmountCur); custTransListContract.parmAmountMST(custTrans.AmountMST); custTransListContract.parmExchRate(custTrans.ExchRate); custTransListContract.parmRemainAmount(custTrans.remainAmountCur()); custTransListContract.parmCurrencyCode(custTrans.CurrencyCode); custTransactionsList.addEnd(custTransListContract); } response.parmTransactionData(custTransactionsList); } } catch(errorEx) { throw error(strFmt("Validation failed for customer %1.",custAccount, errorEx.Message)); } catch (Exception::CLRError) { System.Exception ex = CLRInterop::getLastException(); throw error(strFmt("Validation failed for customer %1.",custAccount, ex.Message)); } return response; } }

JSON Input

{
    "_requestedCustomer": 
    {
        "dataAreaId": "SE02",
        "CustomerAccount": "C0002"
    }
}
        

JSON Output

{
    "$id": "1",
    "Transactions": [
        {
            "$id": "2",
            "Channel": "Site1",
            "Customer Id": "TestCustomer",
            "Transaction type": "Sales order",
            "Date": "11/12/2023",
            "Description": "Credit IN000001VR6 SO SE02-12345VR6 11/12/2023",
            "Amount in currency": -2500.0,
            "Currency": "SEK",
            "Amount in accounting currency": -2500.0,
            "Exchange rate": 100.0,
            "Balance": -2500.0
        },
        {
            "$id": "3",
            "Channel": "Site1",
            "Customer Id": "TestCustomer",
            "Transaction type": "Sales order",
            "Date": "11/12/2023",
            "Description": "Credit IN000001VR7 SO SE02-12345VR7 11/12/2023",
            "Amount in currency": -2500.0,
            "Currency": "SEK",
            "Amount in accounting currency": -2500.0,
            "Exchange rate": 100.0,
            "Balance": -2500.0
        }
    ]
}
        

Creating Dependent Tasks in Dynamics 365 Finance and Operations Batch Jobs with X++ Code

Batch processing is a critical component in handling large-scale data operations within Dynamics 365 Finance and Operations (D365FO). Often, there's a need to create dependent tasks within batch jobs to ensure proper sequencing and execution. In this blog post, we will explore how to create dependent tasks using X++ code in D365FO, based on the provided example.

Understanding the Code

    BatchHeader batchHeader = BatchHeader::construct();

// First task (your first batch job)
DMFBatchImporter batchImporter = new DMFBatchImporter();

batchImporter.batchInfo().parmBatchExecute(NoYes::Yes);
batchImporter.parmReadyForBatchRun(true);
DMFExecutionId batchExecutionId = DMFPackageImporter::PrepareDefinitionGroupForImport(definitionGroupName, executionId, dataAreaId, true);
batchImporter.parmExecutionId(batchExecutionId);

batchHeader.addTask(batchImporter);
batchHeader.addRuntimeTask(batchImporter, BatchHeader::getCurrentBatchTask().RecId);

// Add your second batch job here
TestIntegrationBatch integrationBatch = new TestIntegrationBatch();
integrationBatch.parmLogRecId(logRecId);
integrationBatch.batchInfo().parmGroupId(definition.BatchGroupId);

batchHeader.parmCaption(strFmt('%1 - Test Log - %2', TestIntegrationBatch::description(), logRecId));
// Add second task
batchHeader.addRuntimeTask(integrationBatch, BatchHeader::getCurrentBatchTask().RecId);
// Add dependency
batchHeader.addDependency(integrationBatch, batchImporter, BatchDependencyStatus::FinishedOrError);
batchHeader.save();

  

Step-by-Step Guide on Creating Dependent Tasks

1. Batch Header Initialization:

   Create a new instance of BatchHeader to represent the batch job.

2. First Task - DMFBatchImporter:

   Instantiate the primary task (DMFBatchImporter). Set necessary parameters for batch execution. Prepare the execution ID using DMFPackageImporter::PrepareDefinitionGroupForImport. Add the task to the batch header using addTask. Add the task as a runtime task using addRuntimeTask.

3. Second Task - TestIntegrationBatch:

   Instantiate the secondary task (TestIntegrationBatch). Set any required parameters for this task.

4. Batch Header Configuration:

   Set the caption for the batch header for better identification. Add the secondary task as a runtime task. Define a dependency between tasks using addDependency. In this case, the dependency is set to FinishedOrError, meaning the second task will execute only when the first task finishes successfully or encounters an error.

5. Save Batch Header:

   Save the configured batch header to persist the changes.

Conclusion

Creating dependent tasks in batch jobs is essential for maintaining the proper flow of data processing in Dynamics 365 Finance and Operations. The provided X++ code showcases the integration of two tasks with a dependency relationship. Customize this example according to your specific business requirements and extend the logic as needed to handle more complex scenarios in your batch processing workflows.

How to send Lasernet report PDF on email.

Calling Lasernet Report from X++ Code in Dynamics 365 Finance and Operations

Published on October 4, 2023 by Your Name

Hi All,

I hope everybody is doing great and learning isn't stopped. Today, I am here with another article that will help us call a Lasernet report from X++ code in Dynamics 365 Finance and Operations. Let me explain my requirement. I have a requirement to send the SalesPackingSlipReport over email, but we don't want to use the standard report designs because we have implemented the ISV solution "Lasernet." So, here comes the challenge: how can we call it? I got some input from the below blog, but after that, I faced lots of problems, but finally, I have achieved it.

Lasernet User Guide

Prerequisites to follow
step 1 :

class FPPrintReport
{
    public static void main(Args _args)
    {
        CustPackingSlipJour custPackingSlipJour = CustPackingSlipJour::findRecId(5637146826);
        FPPrintReport::sendPackingSlipByEmail('200030-SHI-UK01', custPackingSlipJour, 
        	'vijay.yelmame14@gmail.com', 'Test.pdf');
    }

    public static void sendPackingSlipByEmail(WHSShipmentId _shipmentId, 
    	CustPackingSlipJour custPackingSlipJour, Email _ToEmail, Filename _fileName)
    {
        CustFormletterParameters custFormParm = CustFormletterParameters::find();

        if (custFormParm.TestEnableEmailPackSlipReport)
        {
            SalesPackingSlipController formLetterController = SalesPackingSlipController::construct();
            SRSPrintDestinationSettings destinationSettings = new SRSPrintDestinationSettings();
            destinationSettings.printMediumType(SRSPrintMediumType::LAC);

            LACDestinationSettings LACDestinationSettings = new LACDestinationSettings();
            LACDestinationSettings.destTypes4Print(LACDestTypes4Print::Email);
            
            LACDestinationSettings.emailFrom(custFormParm.TestFromEmailAddress);
            LACDestinationSettings.emailTo(_ToEmail);
            LACDestinationSettings.emailSubject(strFmt(custFormParm.TestEmailSubject, _shipmentId));
            LACDestinationSettings.emailBody(custFormParm.TestEmailBody);
            LACDestinationSettings.allowForcedReRun(NoYes::Yes);
            LACDestinationSettings.emailFromName('Test Test');

            destinationSettings.lacDestinationSettings(LACDestinationSettings);

            LACReport report = LACReport::find(ssrsReportStr(Salespackingslip, Report));
            LACResendReport::resendReportFromRecord(report.ReportName, custPackingSlipJour, destinationSettings, true);
        }
    }
}

That's it! You can now follow these steps to call Lasernet reports from your X++ code in Dynamics 365 Finance and Operations. This solution should help you send your SalesPackingSlipReport over email using Lasernet.

If you have any questions or encounter any issues, please feel free to ask. Happy coding!

X++ Code to import file using data entity

internal final class TestDataEntityImport

{

    public static void main(Args _args)

    {

        FileUploadTemporaryStorageResult    fileUpload;

        AsciiStreamIo                       file;

        System.IO.Stream                    stream;

        fileUpload  = File::GetFileFromUser() as FileUploadTemporaryStorageResult;

        file        = AsciiStreamIo::constructForRead(fileUpload.openResult());

        stream      = file.getStream();

        

        TestDataEntityImport  TestDataEntityImport = new TestDataEntityImport();

        TestDataEntityImport.importFromBlob(stream,fileUpload.getFileName());

    }

    public DMFDefinitionGroup findDMFDefinitionGroup(Filename   _fileName)

    {

        DMFDefinitionGroup definitionGroup;

        

        if (strStartsWith(_fileName, 'Test'))

        {

            select firstonly definitionGroup

                where definitionGroup.DefinitionGroupName == 'TestVendorPlantImport'; //DMF import data project

        }

        return definitionGroup;

    }

    public DMFDefinitionGroupEntity findDMFDefinitionGroupEntity(DMFDefinitionGroup _definitionGroup)

    {

        DMFDefinitionGroupEntity definitionGroupEntity;

        DMFEntity dmfEntity;

        select firstonly RecId, Entity from definitionGroupEntity

            exists join dmfEntity

        where definitionGroupEntity.DefinitionGroup == _definitionGroup.DefinitionGroupName

           && dmfEntity.EntityName == definitionGroupEntity.Entity;

        if (!definitionGroupEntity)

        {

            throw error(strFmt("@DMF:DMFNoEntityExists", _definitionGroup.DefinitionGroupName));

        }

        return definitionGroupEntity;

    }

    public DMFLocalFilePath applyTransforms(SharedServiceUnitFileID _uploadedStatement, DMFDefinitionGroup definitionGroup)

    {

        DMFDefinitionGroupEntity    definitionGroupEntity = this.findDMFDefinitionGroupEntity(definitionGroup);

        DMFExecutionId              executionId = DMFUtil::setupNewExecution(definitionGroup.DefinitionGroupName);

        DMFDefinitionGroupExecution execution = DMFDefinitionGroupExecution::find(

            definitionGroup.DefinitionGroupName,

            definitionGroupEntity.Entity,

            executionId,

            true);

        execution.IsTransformed = NoYes::No;

        DMFLocalFilePath filePath = execution.applyTransforms(_uploadedStatement);

        DMFExecution e = DMFExecution::find(executionId, true);

        e.delete();

        return filePath;

    }

    public void importFromBlob(System.IO.Stream  _memory, str _fileName)

    {

        SharedServiceUnitFileID     fileId;

        DMFDefinitionGroup          definitionGroup;

        DMFDefinitionGroupEntity    definitionGroupEntity;

        DMFExecutionId              executionId;

        DMFDefinitionGroupExecution execution;

        //Should be used to get file into FileUploadTemporaryStorageResult object

        FileUploadTemporaryStorageResult result = File::SendFileToTempStore_GetResult(_memory, _fileName);

        if (result && result.getUploadStatus())

        {

            fileId = result.getFileId();

            definitionGroup = this.findDMFDefinitionGroup(_fileName);

            this.applyTransforms(fileId, definitionGroup);

            definitionGroupEntity = this.findDMFDefinitionGroupEntity(definitionGroup);

            executionId = DMFUtil::setupNewExecution(definitionGroup.DefinitionGroupName);

            // Find execution

            execution = DMFDefinitionGroupExecution::find(definitionGroup.DefinitionGroupName, definitionGroupEntity.Entity, executionId, true);

            execution.FilePath = fileId;

            execution.IsTransformed = NoYes::Yes;

            execution.IsSelected = NoYes::Yes;

            execution.ExecuteTargetStep = NoYes::Yes;

            execution.update();

            setPrefix(strFmt("@SYS73667", _fileName));

            // Import the file via quick import DMF

            DMFQuickImportExport::doPGImport(definitionGroup.DefinitionGroupName, executionId, true);

            //deletes file

            result.deleteResult();

        }

    }

}

Data migration and integration are critical aspects of any business application, and Microsoft Dynamics 365 Finance and Operations (D365FO) offers a powerful toolset to facilitate these tasks. One of the key features for importing data is the Data Management framework (DMF). In this blog post, we'll explore how to use X++ code to import files using the Data Management framework in D365FO. This code is useful in scenarios where you want to call data entity import throgh integration and also by this code you dont need to worry about how many columns user is going to add later.

Background

The X++ code provided in this blog post demonstrates how to import files using the Data Management framework in D365FO. This code is encapsulated within the TestDataEntityImport class and consists of several methods that work together to achieve a successful file import.

internal final class TestDataEntityImport
{
    public static void main(Args _args)
    {
        FileUploadTemporaryStorageResult fileUpload;
        AsciiStreamIo file;
        System.IO.Stream stream;

        fileUpload = File::GetFileFromUser() as FileUploadTemporaryStorageResult;
        file = AsciiStreamIo::constructForRead(fileUpload.openResult());
        stream = file.getStream();
        
        TestDataEntityImport TestDataEntityImport = new TestDataEntityImport();
        TestDataEntityImport.importFromBlob(stream, fileUpload.getFileName());
    }

    public DMFDefinitionGroup findDefinitionGroup(Filename _fileName)
    {
        DMFDefinitionGroup definitionGroup;
        
        if (strStartsWith(_fileName, 'Test'))
        {
            select firstonly definitionGroup
             where definitionGroup.DefinitionGroupName == 'TestVendorPlantImport'; 
                //DMF import data project
        }

        return definitionGroup;
    }
    public DMFLocalFilePath applyTransforms(SharedServiceUnitFileID _uploadedStatement, DMFDefinitionGroup definitionGroup)
    {
        DMFDefinitionGroupEntity    definitionGroupEntity = this.findDMFDefinitionGroupEntity(definitionGroup);
        DMFExecutionId              executionId = DMFUtil::setupNewExecution(definitionGroup.DefinitionGroupName);

        DMFDefinitionGroupExecution execution = DMFDefinitionGroupExecution::find(
            definitionGroup.DefinitionGroupName,
            definitionGroupEntity.Entity,
            executionId,
            true);

        execution.IsTransformed = NoYes::No;
        DMFLocalFilePath filePath = execution.applyTransforms(_uploadedStatement);

        DMFExecution e = DMFExecution::find(executionId, true);
        e.delete();

        return filePath;
    }

	public void importFromBlob(System.IO.Stream _memory, str _fileName)
    {
        SharedServiceUnitFileID fileId;
        DMFDefinitionGroup definitionGroup;
        DMFDefinitionGroupEntity definitionGroupEntity;
        DMFExecutionId executionId;
        DMFDefinitionGroupExecution execution;

        // Should be used to get file into FileUploadTemporaryStorageResult object
        FileUploadTemporaryStorageResult result 
        	= File::SendFileToTempStore_GetResult(_memory, _fileName);

        if (result && result.getUploadStatus())
        {
            fileId = result.getFileId();
            definitionGroup = this.findDefinitionGroup(_fileName);
            this.applyTransforms(fileId, definitionGroup);

            definitionGroupEntity = this.findDMFDefinitionGroupEntity(definitionGroup);
            executionId = DMFUtil::setupNewExecution(definitionGroup.DefinitionGroupName);

            // Find execution
            execution = DMFDefinitionGroupExecution::find(
                definitionGroup.DefinitionGroupName,
                definitionGroupEntity.Entity,
                executionId,
                true
            );
            
            execution.FilePath = fileId;
            execution.IsTransformed = NoYes::Yes;
            execution.IsSelected = NoYes::Yes;
            execution.ExecuteTargetStep = NoYes::Yes;
            execution.update();

            setPrefix(strFmt("@SYS73667", _fileName));

            // Import the file via quick import DMF
            DMFQuickImportExport::doPGImport(definitionGroup.DefinitionGroupName, executionId, true);

            // Deletes file
            result.deleteResult();
        }
    }
}

Getting Started

The main method serves as the entry point for the file import process. Let's break down the code step by step:

1. File Upload: The code begins by getting a file from the user using the File::GetFileFromUser() method. The file is uploaded and stored in temporary storage.
2. File Reading: The uploaded file is then read using an AsciiStreamIo object. This object provides methods to read data from the uploaded file.
3. Stream Handling: The stream variable is assigned the stream of the file data, which will be used to process the contents of the file.

Conclusion

In this blog post, we've explored how to use X++ code to import files using the Data Management framework in Dynamics 365 Finance and Operations. The provided code demonstrates the step-by-step process of uploading a file, identifying the appropriate DMF Definition Group and Entity, applying transformations, and executing the import.

The Data Management framework in D365FO simplifies data migration and integration tasks, enabling organizations to efficiently import and process large volumes of data. By leveraging the power of X++ and the DMF, businesses can ensure accurate and streamlined data management within their Dynamics 365 environment.

Attributes cannot be deleted while dependent Provisioned channel product attribute exist. Delete dependent Provisioned channel product attribute and try again.

Deleting Attributes with Dependent Provisioned Channel Product Attributes

Struggling to remove attributes due to linked Provisioned channel product attributes? Discover a simple solution below!

The Problem:

Trying to delete attributes, but encountering obstacles due to connected Provisioned channel product attributes.

The Solution:

Follow these steps to regain control:

1. Step 1: Access the Table Browser by adding below line after your dynamics url
   /?mi=SysTableBrowser&prt&limitednav=true&TableName=RETAILPROVISIONEDCHANNELPRODUCTATTRIBUTE&cmp=dat
2. Step 2: Identify Linked Records
   Locate records connected to the attribute you want to delete. These ties are causing the issue.
3. Step 3: Delete Dependent Records
   Bid farewell to linked records to break the dependency.

For more insights and learning on #MicrosoftLearn and #D365FO, check out Microsoft Learn's Dynamics 365 Finance and Operations resources.

How to send SalesPackingSlip report over the email to Customer in D365FO using X++ code

Hi All,

In this blog we are going to learn about how to generate a Sales Packing Slip report and send it to the customer's primary email address.

Step 1: Create a new class

internal final class TestPackingSlipJournalExportService
{
    SRSCatalogItemName reportDesignLocal;
    str documentTitle;
    System.IO.MemoryStream reportMemoryStream;
    SRSPrintMediumType printMedium;
    LanguageId languageId;
    System.Byte[] reportBytes;

    public static TestPackingSlipJournalExportService construct(SRSPrintMediumType _printMedium)
    {
        TestPackingSlipJournalExportService service = new TestPackingSlipJournalExportService();
        service.parmPrintMedium(_printMedium);
        return service;
    }

    public SRSPrintMediumType parmPrintMedium(SRSPrintMediumType _printMedium = printMedium)
    {
        printMedium = _printMedium;
        return printMedium;
    }

   
    /// Export packing slip journal.   
    public System.Byte[] exportPackingSlipJournal(RecId _custPackingSlipJourRecId, str _fileName)
    {
        SalesPackingSlipContract salesPackingSlipContract;
        SalesPackingSlipController formLetterController = SalesPackingSlipController::construct();
        CustPackingSlipJour custPackingSlipJour = CustPackingSlipJour::findRecId(_custPackingSlipJourRecId);

        Common printMgmtReferencedTable;
        FormLetterReport formLetterReport;
        PrintMgmtPrintSettingDetail printSettingDetail;
        SalesTable salesTable = custPackingSlipJour.salesTable();

        PrintMgmtReportFormatName printMgmtReportFormatName = PrintMgmtDocType::construct(PrintMgmtDocumentType::SalesOrderPackingSlip).getDefaultReportFormat();
        reportDesignLocal = printMgmtReportFormatName;

        if (!reportDesignLocal)
        {
            reportDesignLocal = ssrsReportStr(SalesPackingSlip, Report);
        }

        formLetterReport = FormLetterReport::construct(PrintMgmtDocumentType::SalesOrderPackingSlip);

        // Determine where to start looking for Print Mgmt settings
        printMgmtReferencedTable = salesTable;
        languageId = salesTable.LanguageId ? salesTable.LanguageId : custPackingSlipJour.LanguageId;

        formLetterReport.loadPrintSettings(custPackingSlipJour, printMgmtReferencedTable, custPackingSlipJour.LanguageId);

        if (formLetterReport.moveNextPrintSetting())
        {
            printSettingDetail = formLetterReport.getCurrentPrintSetting();
            formLetterReport.parmReportRun().loadSettingDetail(printSettingDetail);
        }

        formLetterReport.parmPrintType(PrintCopyOriginal::Original);
        salesPackingSlipContract = new SalesPackingSlipContract();

        salesPackingSlipContract.parmRecordId(custPackingSlipJour.RecId);
        salesPackingSlipContract.parmTableId(custPackingSlipJour.TableId);
        salesPackingSlipContract.parmDocumentTitle("@ExtendedItallianLocalization:DeliveryNote");

        this.generateReport(salesPackingSlipContract, _fileName);
        return this.getReportBytes();
    }

    private void generateReport(Object _rdpContract, str _fileName)
    {
        SrsReportRunController srsReportRunController = new SrsReportRunController();
        srsReportRunController.parmReportName(reportDesignLocal);
        srsReportRunController.parmExecutionMode(SysOperationExecutionMode::Synchronous);
        srsReportRunController.parmShowDialog(false);
        srsReportRunController.parmReportContract().parmRdpContract(_rdpContract);

        if (languageId)
        {
            srsReportRunController.parmReportContract().parmRdlContract().parmLanguageId(languageId);
            srsReportRunController.parmReportContract().parmRdlContract().parmLabelLanguageId(languageId);
        }

        srsReportRunController.parmReportContract().parmReportExecutionInfo(new SRSReportExecutionInfo());
        srsReportRunController.parmReportContract().parmReportServerConfig(SRSConfiguration::getDefaultServerConfiguration());

        SRSPrintDestinationSettings printerSettings = srsReportRunController.parmReportContract().parmPrintSettings();
        printerSettings.printMediumType(printMedium);
        printerSettings.fileFormat(SRSReportFileFormat::PDF);
        printerSettings.parmFileName(_fileName);
        printerSettings.overwriteFile(true);

        SRSReportRunService srsReportRunService = new SRSReportRunService();
        srsReportRunService.getReportDataContract(srsReportRunController.parmReportContract().parmReportName());
        srsReportRunService.preRunReport(srsReportRunController.parmReportContract());

        Map reportParametersMap = srsReportRunService.createParamMapFromContract(srsReportRunController.parmReportContract());
        Microsoft.Dynamics.AX.Framework.Reporting.Shared.ReportingService.ParameterValue[] parameterValueArray = SrsReportRunUtil::getParameterValueArray(reportParametersMap);

        SRSProxy srsProxy = SRSProxy::constructWithConfiguration(srsReportRunController.parmReportContract().parmReportServerConfig());
        // Actual rendering to byte array
        reportBytes = srsProxy.renderReportToByteArray(srsReportRunController.parmreportcontract().parmreportpath(), parameterValueArray, printerSettings.fileFormat(), printerSettings.deviceinfo());
    }

    public System.Byte[] getReportBytes()
    {
        return reportBytes;
    }
}

    

Step 2: Call the above-created class and get the report bytes

Step 3: Convert the report byte into a stream and pass it as an attachment to the email

You can get the following 3 parameters like below:

• CustPackingSlipJour = CustPackingSlipJour::findRecId(_custPackingSlipJourRecId);
• Email = CustPackingSlipJour.salesTable().customerEmail();
• FileName = "Test.pdf"

public static void sendPackingSlipByEmail(CustPackingSlipJour _custPackingSlipJour, Email _ToEmail, Filename _fileName)
{
    TestPackingSlipJournalExportService service = TestPackingSlipJournalExportService::construct(SRSPrintMediumType::File);
    System.Byte[] reportBytes = service.exportPackingSlipJournal(_custPackingSlipJour.RecId, _fileName);

    if (reportBytes)
    {
        SysMailerMessageBuilder messageBuilder = new SysMailerMessageBuilder();

        try
        {
            System.IO.Stream stream = new System.IO.MemoryStream(reportBytes);
            stream.Position = 0;
            messageBuilder.setBody("Packing Slip id - " + _custPackingSlipJour.PackingSlipId);
            messageBuilder.setSubject("Packing slip journal confirmation");
            messageBuilder.addTo(_ToEmail);
            messageBuilder.addAttachment(stream, _fileName);
            messageBuilder.setFrom('no-reply@Test.com');

            SysMailerFactory::sendNonInteractive(messageBuilder.getMessage());
        }
        catch
        {
            exceptionTextFallThrough();
        }
    }
}

    

Step 4: Result in email

If Condition in Computed Column

Hi all,

Here, we will see how to use the if condition in a computed column. In my requirement, I want to return 0 if RefType is SaftyInvent; otherwise, the value of future days from the same view.

For detailed understanding about computed columns, please check the previous blog.

TestReqTransView is a view created using the ReqTrans table.

X++ Code

private static server str compColumnDelayDays()
{
    DictView reqTransView = new DictView(tableNum(TestReqTransView));
    str reqTransDs = reqTransView.query().dataSourceTable(tableNum(ReqTrans)).name();

    return SysComputedColumn::if(
        SysComputedColumn::equalExpression(
            SysComputedColumn::comparisonField(
                dataentityviewstr(TestReqTransView),
                reqTransDs,
                fieldStr(ReqTrans, Reftype)
            ),
            SysComputedColumn::comparisonLiteral(ReqRefType::SafetyInvent)
        ),
        '0',
        SysComputedColumn::returnField(
            tableStr(TestReqTransView),
            reqTransDs,
            fieldId2name(tableNum(TestReqTransView), fieldNum(TestReqTransView, FUTURESDAYS))
        )
    );
}
    

Mark invent quantity in D365FO using X++

   

Hi All,
Below is the code to mark sales line with correspond Purch line. I used this for completing the marking for migrated purchase line.

X++ Code

 /// <summary>
 /// Mark sales line with purch line
 /// </summary>
 /// <param name = "_issueInventTransId">SalesLine inventrans Recid</param>
 /// <param name = "_receiptInventTransId">PurchLine inventtrans RecId</param>

 public static void completeInventMarking(InventTransId _issueInventTransId, InventTransId _receiptInventTransId)
    {

        InventTransId       issueInventTransId   = _issueInventTransId;
        InventTransId       receiptInventTransId = _receiptInventTransId;
        TmpInventTransMark  tmpInventTransMark;
        Map                 mapUpdated;

        InventTransOriginId receiptInventTransOriginId  =                         InventTransOrigin::findByInventTransId(receiptInventTransId).RecId;

        InventTrans         receiptInventTrans  = InventTrans::findByInventTransOrigin(receiptInventTransOriginId);

         InventTransOriginId issueInventTransOriginId    =   InventTransOrigin::findByInventTransId(issueInventTransId).RecId;

        InventTrans         issueInventTrans            =   InventTrans::findByInventTransOrigin(issueInventTransOriginId);

    InventTransMarkCollection collection = TmpInventTransMark::markingCollection(             InventTransOrigin::find(receiptInventTransOriginId),receiptInventTrans.inventDim(),         receiptInventTrans.Qty);

 collection.insertCollectionToTmpTable(tmpInventTransMark); 

 select firstonly tmpInventTransMark
            where tmpInventTransMark.InventTransOrigin == issueInventTrans.InventTransOrigin                            && tmpInventTransMark.InventDimId       == issueInventTrans.InventDimId;

 if (tmpInventTransMark.RecId != 0)
{
            Qty qtyToMark = issueInventTrans.Qty;

            tmpInventTransMark.QtyMarkNow =  qtyToMark;
            tmpInventTransMark.QtyRemain  -= tmpInventTransMark.QtyMarkNow;

            mapUpdated = new Map(Types::Int64, Types::Record);

            mapUpdated.insert(tmpInventTransMark.RecId, tmpInventTransMark);

             TmpInventTransMark::updateTmpMark(
                        receiptInventTransOriginId,
                        receiptInventTrans.inventDim(),
                        -qtyToMark,
                        mapUpdated.pack());
        }

    }

SalesPackingSlip Report and saving it as a PDF file using x++ code

Calling Sales Packing Slip Report through X++ Code

Hello Blogger Viewers,

Today, I am excited to share with you some X++ code that allows you to call the Sales Packing Slip report programmatically. This can be useful in scenarios where you need to automate the process of generating packing slip reports. Let's dive into the code!

        
SrsReportRunController ssrsController = new SrsReportRunController();
SalesPackingSlipContract salesPackingSlipContract = new SalesPackingSlipContract();
CustPackingSlipJour custPackingSlipJour;
SRSPrintDestinationSettings printerSettings;

select custPackingSlipJour where custPackingSlipJour.PackingSlipId == "200258-PAS-UK01";

// Define which report design to run.
ssrsController.parmReportName(ssrsReportStr(SalesPackingSlip, Report));

// Define how we want to execute the report (right now or batch style).
ssrsController.parmExecutionMode(SysOperationExecutionMode::Synchronous);

// Hide the report dialog.
ssrsController.parmShowDialog(false);

// Set the record and table IDs for the report contract.
salesPackingSlipContract.parmRecordId(custPackingSlipJour.RecId);
salesPackingSlipContract.parmTableId(custPackingSlipJour.TableId);

// Link the contract to the controller so we know how to run the data provider.
ssrsController.parmReportContract().parmRdpContract(salesPackingSlipContract);

// Link the printer settings to the controller.
printerSettings = ssrsController.parmReportContract().parmPrintSettings();

// Set the print medium type to HTML and always overwrite the file if it exists.
printerSettings.printMediumType(SRSPrintMediumType::File);
printerSettings.fileFormat(SRSReportFileFormat::PDF);
printerSettings.overwriteFile(true);
printerSettings.fileName(@'C:\'+'PackingListReport'+custPackingSlipJour.PackingSlipId+'.pdf');

// Start the report execution.
ssrsController.startOperation();
        
    

After executing this code, you will be able to see the generated PDF file in your "Downloads" folder. This approach provides a convenient way to automate the process of generating Sales Packing Slip reports.

I hope you find this code snippet helpful for your X++ development. If you have any questions or suggestions, feel free to leave a comment below.

Happy coding!

how to create number sequence in d365fo

 Hi All, 

Welcome to Blog.

Today we are going to learn how to create number sequence. But before we start let's understand about number sequence framework. Microsoft Dynamics AX has a number sequence framework to generate alphanumeric number sequences that are used to identify transaction documents such as purchase orders, Sales Orders. This topic describes how to implement the number sequence framework for a new module in Microsoft Dynamics AX. In this topic will learn how to create new number sequence reference in Accounts Payable module and will use newly created number sequence in our custom form.

Steps to follow one new number using number sequence:

     1.   Create new string type EDT.

 Name it like: TutBikeId or according to your requirement.

Set label and size properties.

2.    Create new class to set Number sequence data type.

Name it like: ModulenameBikeIdNumSeq , My muodulename is Test so I am using Test as prefix for all the objects.

Internal final class TestBikeIdNumSeq extends NumberSeqApplicationModule

{

[SubscribesTo(classstr(NumberSeqGlobal),delegatestr(NumberSeqGlobal,buildModulesMapDelegate))]

    static void buildModulesMapSubsciber(Map numberSeqModuleNamesMap)
    {

NumberSeqGlobal::addModuleToMap(classnum(TestBikeIdNumSeq), numberSeqModuleNamesMap);

    }

 // this is depend on the which module you want to generate the number sequence.

    public NumberSeqModule numberSeqModule()

    {

        return NumberSeqModule::Cust;

    }

     protected void loadModule()

    {

        NumberSeqDatatype datatype = NumberSeqDatatype::construct();

        datatype.parmDatatypeId(extendedTypeNum(TestBikeId));

        datatype.parmReferenceHelp(literalStr("Unique key used for the Bike iD."));

        datatype.parmWizardIsContinuous(false);

        datatype.parmWizardIsManual(NoYes::No);

        datatype.parmWizardFetchAheadQty(10);

        datatype.parmWizardIsChangeDownAllowed(NoYes::No);

        datatype.parmWizardIsChangeUpAllowed(NoYes::No);

        datatype.parmSortField(1); 

        datatype.addParameterType(NumberSeqParameterType::DataArea, true, false);

        this.create(datatype);

    }

}

 

3.    Create new runnable class to load the number sequence.

internal final class TestBikeIdLoadNumSeq

{   

    public static void main(Args _args)

    {

        TestBikeIdNumSeq TestBikeIdNumSeq = new TestBikeIdNumSeq ();

        TestBikeIdNumSeq.load();

    }

 }

4.    Build and synchronize your project and run the above runnable class using below URL.

F&O url/?cmp=dat&mi=sysclassrunner&cls=TestBikeIdLoadNumSeq 

5.    After running the job, go the parameters form you added the number sequence reference to, then, go to the 'Number sequence' tab and verify that a new row is shown.

In my example, I see the new number sequence reference show on the ‘Accounts receivable parameters’ form.

6.  Next go to Organization administration>Number sequences>Number sequences. Then click the 'Generate' button to run the wizard.

Click Next

Finally, review the 'Completed' page, and click 'Finish'.

Remember the number sequence code generated or find using below filters.

7.    Setup new number code on to AR parameter > number sequence > bike id 

8.    Create new string type field on your custom table.

Set extended type property to above created EDT. Ex- TutBikeId

9.    Override the create method of your form data source and add below code.

public void create(boolean _append = false)
 {

            TestBikeId testBikeId;

            NumberSequenceReference numberSequenceReference; 

            super(_append); 

            ttsbegin;

numberSequenceReference= NumberSeqReference::findReference(extendedTypeNum(TestBikeId));

            if (numberSequenceReference)
            {
                testBikeId = NumberSeq::newGetNum(numberSequenceReference).num();
                TestTutorialBikeTable.BikeId = testBikeId;
            } 

            ttscommit;

        } 

10. Build and synch your project.

11. Create new record on the form and check.

Create table in email body using X++ code.

Hi All,
Today we are going to see how to create table in email body without using email templates. Please refer below example.

Note - Please make sure your email parameter setup is done and you able to send test email.

Expected result: 

X++ Code

internal final class TestJobTableInEmailBody

{

    public static void main(Args _args)

    {

        SysMailerMessageBuilder messageBuilder = new SysMailerMessageBuilder();

        SysInfoLogStr   emailBodyWithHtml;

        EmailBase       fromEmail = 'no-reply-vendorportal@testgroup.com';

        EmailBase       toEmail = 'vijay.yelmame14@gmail.com';

        EmailBase       ccEmail;

        PurchTable      PurchTable;

        boolean emailSend;

        try

        {

            emailBodyWithHtml = "<table border = '1'><tr><td><b>Payment<b></td><td><b>Currency Code<b></td><td><b>DeliveryPostalAddress<b></td><td><b>Delivery Date<b></td></tr>";

            while select * from PurchTable where 

                PurchTable.OrderAccount =='TEst-VEN'

            {

                emailBodyWithHtml += "<tr><td>"+PurchTable.Payment+"</td><td>"+PurchTable.CurrencyCode+"</td><td>"+any2Str(PurchTable.DeliveryPostalAddress)+"</td><td>"+any2Str(PurchTable.DeliveryDate)+"</td></tr>";

            }

            emailBodyWithHtml += "</Table>";

            messageBuilder.setBody(strFmt(strRem(emailBodyWithHtml, '\r')),true);

            messageBuilder.setSubject("Test Email");

            messageBuilder.addTo(toEmail);

            //messageBuilder.addCc(ccEmail);

            messageBuilder.setFrom(fromEmail);

            emailSend = SysMailerFactory::sendNonInteractive(messageBuilder.getMessage());

        }

        catch

        {

            warning("@Res:NotificationEmailNotSent");

        }

    }

}

Create computed column on view in D365FO using created date time column.

Dear All,

In this article will see how to create computed column in view. As we all know view are returning records from SQL from multiple tables, but some time we are getting requirement to create calculated column using the available column. Similarly, in below example as well we are going to create calculated column using createdDateTime field of PurchLine table.

We can achieve this requirement using display method, but it will not give you the filter and sorting options so let's learn and implement it together.

Requirement: Return a date difference between CreatedDateTime and today's date and show values to the form grid with filter and sorting should be available on return value column.

Solution: Create computed column on view, add view as a DataSource on form and add computed column field into grid.

Implementation: 

Step 1: 
Add new static method on view and add code according to your logic.

 
X++ Code for method -

Step 2: Add computed column on view.
Right click on view and select column according to your requirement. 

Step 3: Select method in View method property of new created column.

Step 4: Add DataSource column in form Grid. Assuming you are aware on form design so explaining this step-in details. Link 

Step 5: Build and synchronize your project.

Step 6: Verify SQL level changes: 
Filter views by name in AxDb and find how your column is created.

SQL view for this computed column.

Step Last: Validate changes on form, try to apply filters and sort using standard sorting functionality. 

That's It.

Happy Daxing.

How to apply custom range on AOT query in D365 Finance and Operations

Hi All,

Here in this blog will see how to apply custom range on AOT query.

Requirement: Add range on AOT query to get the records created before given days (createdDateTime - PriorDays)

Steps 1 - Add new field in the parameters. Please refer below screen shot.

Step 2 - Create new class and use attribute for range method. Refer below screen shot.

internal final class TestQueryRangeUtil

{

    

    [QueryRangeFunctionAttribute()]

    public static str greaterThanDateByParameter()

    {

        int relativeDays = SalesParameters::find().TestPriorDays;

        utcdatetime  currentDateTime;

        currentDateTime = DateTimeUtil::applyTimeZoneOffset(DateTimeUtil::getSystemDateTime(),               DateTimeUtil::getUserPreferredTimeZone());

        return '> ' +              SysQueryRangeUtil::value(DateTimeUtil::date(DateTimeUtil::addDays(currentDateTime,relativeDays)));  

    }

}

Step 3:Create range on AOT query and add below given expression as value.

(TESTQueryRangeUtil::greaterThanDateByParameter())

Thats it. Happy Coding.